************************************************************************
SUBROUTINE WEIGHT(AR,H,RL,RLAM,RNPA,RNPI,S,TAP,TC,W0,SFWET,WE)
************************************************************************
* THIS VERSION (10/19/95) IS DIFFERENT FROM OTHER VERSIONS *
* THAT YOU MAY FIND OR HAVE USED *
************************************************************************
* *
* THIS ROUTINE IS DESIGNED TO ESTIMATE THE EMPTY WEIGHT OF A *
* CARGO/TRANSPORT AIRCRAFT (NOT INCLUDING THE WEIGHT OF THE ENGINES) *
* BASED PRIMARILY ON EMPIRICAL RELATIONS SUGGESTED BY RAYMER IN *
* 'AIRCRAFT DESIGN A CONCEPTUAL APPROACH'. A FEW OTHER APPROXIMATIONS *
* HAVE BEEN MADE IN THE INTEREST OF EFFICIENCY. *
* SEVERAL CONSTANTS ARE HARDWIRED INTO THIS CODE AND MUST BE *
* PRE-SELECTED BY THE INSTRUCTOR OR THE USER. *
* FUDGE FACTORS HAVE BEEN INCLUDED TO COMPENSATE FOR THE COMPONENTS *
* OF THE AIRCRAFT WHICH ARE NOT EASILY MODELED, IN THE FUTURE THESE *
* MAY REQUIRE SOME ATTENTION. *
* AS THIS CODE IS DEPENDENT ON HISTORY, IT GIVES WEIGHTS FOR *
* YESTERDAY'S AIRCRAFT AND SHOULD BE UPDATED WHEN EVER POSSIBLE. *
* *
************************************************************************
************************************************************************
* *
* VARIABLE DEFINITION *
* *
* AR - WING ASPECT RATIO X *
* ARH - HORIZONTAL TAIL ASPECT RATIO *
* ARV - VERTICAL TAIL ASPECT RATIO *
* B - WING SPAN (FT) X *
* BH - HORIZONTAL TAIL SPAN (FT) *
* CHT - HORIZONTAL TAIL VOLUME RATIO *
* CVY - VERTICAL TAIL VOLUME RATIO *
* EPSILON- A CORRECTION FACTOR TO COMPENSATE FOR UNACCOUNTED WEIGHTS *
* (ie. FUEL TANKS, LANDING GEAR, ETC.) *
* FW - WIDTH OF THE FUSELAGE AT THE HORIZONTAL TAIL (FT) *
* H - MAX FUSELAGE WIDTH (FT) X *
* HTHV - RATIO OF HORZONTAL TO VERTICAL TAIL HEIGHT *
* RKDOOR - CARGO DOOR CORRECTION FACTOR *
* RKL - TAIL MOMENT ARM CONSTANT *
* RKLAV - LAVORATORY CORRECTION FACTOR *
* RKLG - LANDING GEAR CORRECTION FACTOR *
* RKUH - HORIZONTAL TAIL CORRECTION FACTOR *
* RKWS - WING SHAPE CORRECTION FACTOR *
* RKY - PITCHING RADIUS OF GYRATION *
* RKZ - YAWING RADIUS OF GYRATION *
* RL - FUSELAGE LENGTH (FT) X *
* RLAM - WING HALF CHORD SWEEP ANGLE (RAD) X *
* RLAMH - HORIZONTAL TAIL HALF CHORD SWEEP ANGLE (RAD) *
* RLAMV - VERTICAL TAIL HALF CHORD SWEEP ANGLE (RAD) *
* RLT - EMPENNAGE MOMENT ARM (FT) *
* RN - MAX LOAD FACTOR *
* RNPA - NUMBER OF PASSENGERS X *
* RNPI - NUMBER OF PILOTS X *
* S - WING REFERENCE AREA (FT**2) X *
* SCS - WING CONTROL REFERENCE AREA (FT**2) *
* SE - ELEVATOR REFERENCE AREA (FT**2) *
* SFWET - FUSELAGE WETTED AREA (FT**2) X *
* SH - HORZONTAL TAIL REFERENCE AREA (FT**2) *
* SV - VERTICAL TAIL REFERENCE AREA (FT**2) *
* TAP - WING TAPER RATIO X *
* TC - WING THICKNESS TO CHORD RATIO X *
* TCR - HORIZONTAL TAIL THICKNESS TO CHORD RATIO AT THE ROOT *
* WE - EMPTY WEIGHT (LBS) *
* W0 - MAX GROSS TAKEOFF WEIGHT (LBS) X *
* W1 - WING WEIGHT (LBS) *
* W2 - FUSELAGE WEIGHT (LBS) *
* W3 - EMPENAGE WEIGHT (LBS) *
* W4 - MISCELLANEOUS WEIGHT (LBS) *
* *
* X INDICATES VALUES WHICH MUST BE SUPPLIED *
* *
************************************************************************
IMPLICIT REAL (A-J,O-Z)
************************************************************************
* *
* CONSTANT SPECIFICATION *
* *
* CHT = 1.00 => CONVENTIONAL HORIZONTAL TAIL *
* = 0.875 => ALL MOVING HORIZONTAL TAIL *
* = 0.95 => T - TAIL *
* *
* CVT = 0.085 => CONVENTIONAL VERTICAL TAIL *
* = 0.081 => T - TAIL *
* *
* HTHV = 1.00 => T - TAIL *
* = 0.0 => FUSELAGE MOUNTED TAIL *
* *
* RKDOOR = 1.00 => NO CARGO DOOR *
* = 1.06 => ONE SIDE CARGO DOOR *
* = 1.12 => TWO SIDE CARGO DOORS *
* = 1.25 => TWO SIDE CARGO DOORS AND AN AFT CLAMSHELL DOOR *
* *
* RKL = 0.525 => IF ENGINES ARE WING MOUNTED *
* = 0.475 => IF ENGINES ARE TAIL MOUNTED *
* *
* RKLG = 1.12 => FUSELAGE MOUNTED LANDING GEAR *
* = 1.00 => OTHERWISE *
* *
* RKLAV = 1.11 => LONG RANGE AIRCRAFT *
* = 0.31 => SHORT RANGE AIRCRAFT *
* = 3.90 => BUSINESS AIRCRAFT *
* *
* RKUHT = 1.143 => ALL MOVING HORIZONTAL TAIL *
* = 1.00 => OTHERWISE *
* *
************************************************************************
B=SQRT(AR*S)
CHT = 1.00
CVT = 0.085
HTHV = 0.0
RKDOOR = 1.06
RKL = 0.525
RKLG = 1.0
RKLAV = 1.11
RKUHT = 1.0
RKWS = 0.75*( (1.0+2.0*TAP)/(1.0+TAP) )*(B*TAN(RLAM)/RL)
RLT = RKL*RL
RKY = 0.3*RLT
RKZ = RLT
ARH = 0.59*AR
ARV = 0.23*AR
SV = CVT*B*S/RLT
SH = CHT*S*S/(B*RLT)
BH = SQRT(ARH*SH)
FW = 0.5*H
TCR = TC
RN = 3.5
SCS = 0.15*S
SE = 0.33*SH
RLAMH = RLAM
RLAMV = RLAM
********** WING WEIGHT
W1 = 0.0051*(S**0.649)*(AR)**.60*(W0*RN)**0.557*(TC**(-0.4))
* *(((1.0+TAP)*SCS)**0.1)/(COS(RLAM))
********** FUSELAGE WEIGHT
W2 = 0.328*RKDOOR * RKLG * SQRT(W0*RN) * RL**0.25 * SFWET**0.302
* * (1.0+RKWS)**0.04 * (RL/H)**0.1
********** EMPENNAGE WEIGHT
W3 = ( 0.0379*RKUHT * (1.0 + FW/BH)**(-0.25) * W0**0.639
* * RN**0.1 * SH**0.75 * RKY**0.704 * ARH**0.166
* * ((1.0 + SE/SH)**0.1)/(RLT*COS(RLAMH)) )
* + ( 0.0026*(1.0 + HTHV)**0.225 * W0**0.556 * RN**0.536
* *SQRT(SV/(RLT*TCR))*RKZ**0.875*(ARV**0.35)/COS(RLAMV))
********** MISCELLANEOUS WEIGHTS
W4 = 60.0*RNPI + 32.0*RNPA + RKLAV*RNPA**1.33 + 0.002*W0
******************* EMPTY WEIGHT
WE = (W1 + W2 + W3 + W4)
IF(WE .LT. 27000.0)THEN
EPSILON = 1.44077*(WE**(-0.0272))
ELSE
EPSILON = 1.29863*(WE**(-0.0162))
END IF
WE = WE**EPSILON
w=we
RETURN
END
************************************************************************
************************************************************************